suffling around some files

2 files changed, 222 insertions, 0 deletions

diff --git a/sys/jao-ednc.el b/sys/jao-ednc.el
new file mode 100644
index 0000000..06ed986
--- /dev/null
+++ b/sys/jao-ednc.el
@@ -0,0 +1,118 @@
+;;; jao-ednc.el --- Minibuffer notifications using EDNC  -*- lexical-binding: t; -*-
+
+;; Copyright (C) 2020  jao
+
+;; Author: jao <mail@jao.io>
+;; Keywords: tools, abbrev
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;;  Use the ednc package to provide a notification daemon that uses
+;;  the minibuffer to display them.
+
+;;; Code:
+
+(require 'ednc)
+(require 'jao-minibuffer)
+
+(declare-function tracking-add-buffer "tracking")
+(declare-function tracking-remove-buffer "tracking")
+
+(defvar jao-ednc--count-format "{%d}")
+(defvar jao-ednc--last-notification nil)
+
+(defface jao-ednc-tracking '((t :inherit warning))
+  "Tracking notifications face"
+  :group 'jao-ednc)
+
+(defun jao-ednc--format-last ()
+  (when jao-ednc--last-notification
+    (let ((s (ednc-format-notification jao-ednc--last-notification t)))
+      (replace-regexp-in-string "\n" " " s))))
+
+(defun jao-ednc--count ()
+  (let ((no (length (ednc-notifications))))
+    (if (> no 0) (format jao-ednc--count-format no) "")))
+
+(defvar jao-ednc--handlers ())
+
+(defun jao-ednc-add-handler (app handler)
+  (add-to-list 'jao-ednc--handlers (cons app handler)))
+
+(defun jao-ednc-ignore-app (app)
+  (jao-ednc-add-handler app (lambda (not _) (ednc-dismiss-notification not))))
+
+(defun jao-ednc--default-handler (notification newp)
+  (if newp
+      (progn
+        (tracking-add-buffer (get-buffer ednc-log-name) '(jao-ednc-tracking))
+        (setq jao-ednc--last-notification notification)
+        (jao-minibuffer-push-notification '(:eval (jao-ednc--format-last))))
+    (tracking-remove-buffer (get-buffer ednc-log-name))
+    (setq jao-ednc--last-notification nil)
+    (jao-minibuffer-pop-notification)))
+
+(defun jao-ednc--handler (notification)
+  (alist-get (ednc-notification-app-name notification)
+             jao-ednc--handlers
+             #'jao-ednc--default-handler
+             nil
+             'string=))
+
+(defun jao-ednc--on-notify (old new)
+  (when old (funcall (jao-ednc--handler old) old nil))
+  (when new (funcall (jao-ednc--handler new) new t)))
+
+;;;###autoload
+(defun jao-ednc-setup ()
+  (setq jao-notify-use-messages-p t)
+  (with-eval-after-load "tracking"
+    (add-to-list 'tracking-faces-priorities 'jao-ednc-tracking)
+    (when (listp tracking-shorten-modes)
+      (add-to-list 'tracking-shorten-modes 'ednc-view-mode)))
+  ;; (jao-minibuffer-add-variable '(jao-ednc--count) t)
+  (add-hook 'ednc-notification-presentation-functions #'jao-ednc--on-notify)
+  (ednc-mode))
+
+;;;###autoload
+(defun jao-ednc-pop ()
+  (interactive)
+  (pop-to-buffer-same-window ednc-log-name))
+
+;;;###autoload
+(defun jao-ednc-show ()
+  (interactive)
+  (if jao-ednc--last-notification
+      (ednc-pop-to-notification-in-log-buffer jao-ednc--last-notification)
+    (jao-ednc-pop)))
+
+;;;###autoload
+(defun jao-ednc-invoke-last-action ()
+  (interactive)
+  (if jao-ednc--last-notification
+      (ednc-invoke-action jao-ednc--last-notification)
+    (message "No active notifications"))
+  (jao-minibuffer-pop-notification))
+
+;;;###autoload
+(defun jao-ednc-dismiss ()
+  (interactive)
+  (if jao-ednc--last-notification
+      (ednc-dismiss-notification jao-ednc--last-notification)
+    (jao-minibuffer-pop-notification)))
+
+(provide 'jao-ednc)
+;;; jao-ednc.el ends here
diff --git a/sys/jao-minibuffer.el b/sys/jao-minibuffer.el
new file mode 100644
index 0000000..7104544
--- /dev/null
+++ b/sys/jao-minibuffer.el
@@ -0,0 +1,104 @@
+;;; jao-minibuffer.el --- using the minibuffer to report status  -*- lexical-binding: t; -*-
+
+;; Copyright (C) 2020  jao
+
+;; Author: jao <mail@jao.io>
+;; Keywords: extensions
+
+;; This program is free software; you can redistribute it and/or modify
+;; it under the terms of the GNU General Public License as published by
+;; the Free Software Foundation, either version 3 of the License, or
+;; (at your option) any later version.
+
+;; This program is distributed in the hope that it will be useful,
+;; but WITHOUT ANY WARRANTY; without even the implied warranty of
+;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+;; GNU General Public License for more details.
+
+;; You should have received a copy of the GNU General Public License
+;; along with this program.  If not, see <https://www.gnu.org/licenses/>.
+
+;;; Commentary:
+
+;; Simple asynchronous display of information in the minibuffer.
+
+;;; Code:
+
+(defvar jao-minibuffer-info ())
+(defvar jao-minibuffer-notification nil)
+(defvar jao-minibuffer-align-right-p t)
+(defvar jao-minibuffer-right-margin (if window-system 0 1))
+(defvar jao-minibuffer-maximized-frames-p t)
+(defvar jao-minibuffer-notification-timeout 5)
+
+(defconst jao-minibuffer--name " *Minibuf-0*")
+
+(defun jao-minibuffer--trim (s w)
+  (if (<= (length s) w)
+      (format (format "%%%ds" w) s)
+    (substring s 0 w)))
+
+(defun jao-minibuffer--current ()
+  (with-current-buffer jao-minibuffer--name
+    (buffer-substring (point-min) (point-max))))
+
+(defun jao-minibuffer--aligned (&optional w currentp)
+  (let* ((msg (if currentp
+                  (jao-minibuffer--current)
+                (format-mode-line (or jao-minibuffer-notification
+                                      jao-minibuffer-info))))
+         (msg (propertize (string-trim msg) :minibuffer-message t)))
+    (when (not (string-empty-p msg))
+      (if jao-minibuffer-align-right-p
+          (let* ((mw (if jao-minibuffer-maximized-frames-p
+                         (frame-width)
+                       (window-width (minibuffer-window))))
+                 (w (mod (or w (length (current-message))) mw))
+                 (w (- mw w jao-minibuffer-right-margin)))
+            (if (> w 0) (jao-minibuffer--trim msg w) ""))
+        (concat " · " msg)))))
+
+(defun jao-minibuffer--set-message (msg)
+  (let ((msg (string-trim (replace-regexp-in-string "\n" " " msg))))
+    (concat msg (jao-minibuffer--aligned (length msg) t))))
+
+;;;###autoload
+(defun jao-minibuffer-refresh ()
+  (interactive "")
+  (with-current-buffer jao-minibuffer--name
+    (erase-buffer)
+    (insert (or (jao-minibuffer--aligned) ""))))
+
+;;;###autoload
+(defun jao-minibuffer-add-variable (variable-name &optional append)
+  (add-to-list 'jao-minibuffer-info `(:eval ,variable-name) append))
+
+(defvar jao-minibuffer--notification-timer nil)
+
+(defun jao-minibuffer--start-notification-timer (timeout)
+  (interactive)
+  (when jao-minibuffer--notification-timer
+    (cancel-timer jao-minibuffer--notification-timer))
+  (setq jao-minibuffer--notification-timer
+        (run-with-idle-timer (or timeout jao-minibuffer-notification-timeout)
+                             nil
+                             'jao-minibuffer-pop-notification)))
+
+;;;###autoload
+(defun jao-minibuffer-push-notification (msg &optional timeout)
+  (setq jao-minibuffer-notification msg)
+  (jao-minibuffer--start-notification-timer timeout)
+  (jao-minibuffer-refresh))
+
+;;;###autoload
+(defun jao-minibuffer-pop-notification ()
+  (interactive)
+  (setq jao-minibuffer-notification nil)
+  (jao-minibuffer-refresh))
+
+(setq set-message-function #'jao-minibuffer--set-message)
+(setq clear-message-function #'jao-minibuffer-refresh)
+(setq resize-mini-windows nil)
+
+(provide 'jao-minibuffer)
+;;; jao-minibuffer.el ends here