;; jao-doc-view.el -- Remembering visited documents -*- lexical-binding: t; -*-

;; Copyright (c) 2013, 2015, 2017, 2018, 2019, 2021 Jose Antonio Ortega Ruiz

;; This file is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation; either version 3 of the License, or
;; (at your option) any later version.

;; This file is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <http://www.gnu.org/licenses/>.

;; Author: Jose Antonio Ortega Ruiz <jao@gnu.org>
;; Start date: Fri Feb 15, 2013 01:21

;;; Comentary:

;; Some utilities to keep track of visited documents and their structure.

;;; Code:


;;; Session

(require 'doc-view)

(defvar jao-doc-view-session-file "~/.emacs.d/cache/doc-view-session.eld")
(defvar-local jao-doc-view--is-pdf nil)

(defun jao-doc-view-session-mark (path) (setq-local jao-doc-view--is-pdf path))
(defun jao-doc-view--is-pdf ()
  (or jao-doc-view--is-pdf
      (when (derived-mode-p 'doc-view-mode 'pdf-view-mode)
        (buffer-file-name))))

(defun jao-doc-view--read-file (file)
  (let ((buff (find-file-noselect file)))
    (ignore-errors
      (with-current-buffer buff
        (goto-char (point-min)))
      (read buff))))

(defun jao-doc-view--save-to-file (file value)
  (with-current-buffer (find-file-noselect file)
    (erase-buffer)
    (insert (format "%S" value))
    (save-buffer)))

(defun jao-doc-view-session (&optional file)
  (let ((file (or file jao-doc-view-session-file)))
    (jao-doc-view--read-file file)))

(defun jao-doc-view-save-session (&optional skip-current)
  (interactive)
  (let ((docs '())
        (cb (when skip-current (current-buffer))))
    (dolist (b (buffer-list))
      (with-current-buffer b
        (when-let (fn (and (not (eq cb b)) (jao-doc-view--is-pdf)))
          (add-to-list 'docs fn))))
    (when (> (length docs) 0)
      (jao-doc-view--save-to-file jao-doc-view-session-file docs))))

(defun jao-doc-view--save-session-1 ()
  (when (jao-doc-view--is-pdf) (jao-doc-view-save-session t)))

(defvar jao-doc-view-inhibit-session-save nil)

(defun jao-doc-view--save-session ()
  (let ((inhibit-message t)
        (message-log-max nil))
    (when (not jao-doc-view-inhibit-session-save)
      (jao-doc-view-save-session))
    t))

(add-hook 'kill-emacs-query-functions #'jao-doc-view--save-session)
(add-hook 'kill-buffer-hook #'jao-doc-view--save-session-1)
(add-hook 'doc-view-mode-hook #'jao-doc-view--save-session)
(add-hook 'pdf-view-mode-hook #'jao-doc-view--save-session)


;;; PDF info

(defvar-local jao--pdf-outline nil)

(defmacro jao-doc-view--pdf-call (a b &rest args)
  `(cond ((derived-mode-p 'pdf-view-mode) (,a ,@args))
         ((derived-mode-p 'doc-view-mode) (,b ,@args))))

(defun jao-doc-view-is-pdf (file) (string-match-p ".*\\.pdf$" file))

(defun jao-doc-view-title->file (title)
  (concat (mapconcat 'downcase (split-string title nil t) "-") ".pdf"))

(defun jao-doc-view-current-page ()
  (jao-doc-view--pdf-call pdf-view-current-page doc-view-current-page))

(defun jao-doc-view-goto-page (page &optional height)
  (when page
    (jao-doc-view--pdf-call pdf-view-goto-page doc-view-goto-page page))
  (when (and height (derived-mode-p 'pdf-view-mode))
    (image-set-window-vscroll
     (round (/ (* height (cdr (pdf-view-image-size))) (frame-char-height))))))

(defun jao-doc-view-pdf-outline (&optional file-name)
  (if (derived-mode-p 'pdf-view-mode)
      (pdf-info-outline)
    (let* ((outline nil)
           (fn (or file-name (buffer-file-name) jao-doc-view--imenu-file))
           (fn (shell-quote-argument (expand-file-name fn))))
      (with-temp-buffer
        (insert (shell-command-to-string (format "mutool show %s outline" fn)))
        (goto-char (point-min))
        (while (re-search-forward ".+\\(\t+\\)\"\\(.+\\)\"\t#\\([0-9]+\\)," nil t)
          (push `((level . ,(length (match-string 1)))
                  (title . ,(match-string 2))
                  (page . ,(string-to-number (match-string 3))))
                outline)))
      (nreverse outline))))

(defun jao-doc-view-section-title (&optional page file-name)
  (when (not jao--pdf-outline)
    (setq-local jao--pdf-outline (jao-doc-view-pdf-outline file-name)))
  (let ((page (or page (jao-doc-view-current-page)))
        (outline jao--pdf-outline)
        (cur-page 0)
        (cur-title (jao-doc-view-title (or file-name buffer-file-name "title"))))
    (while (and (car outline) (< cur-page page))
      (setq cur-page (cdr (assoc 'page (car outline))))
      (when (<= cur-page page)
        (setq cur-title (cdr (assoc 'title (car outline)))))
      (setq outline (cdr outline)))
    (replace-regexp-in-string "[[:blank:]]+" " " cur-title)))

(defun jao-doc-view-title (&optional fname)
  (if (or fname (not (derived-mode-p 'doc-view-mode 'pdf-view-mode)))
      (let ((base (file-name-base (or fname (buffer-file-name)))))
        (capitalize (replace-regexp-in-string "-" " " base)))
    (or (jao-doc-view-section-title)
        (when buffer-file-name (jao-doc-view-title buffer-file-name)))))


;;; imenu
(defvar-local jao-doc-view--imenu-file nil)
(defvar-local jao-doc-view--goer 'jao-doc-view-goto-page)

(defun jao-doc-view--enable-imenu (&optional file-name goto-page)
  (setq-local imenu-create-index-function #'jao-doc-view--imenu-create-index
              jao-doc-view--imenu-file (or file-name jao-doc-view--imenu-file)
              jao-doc-view--goer (or goto-page 'jao-doc-view-goto-page))
  (imenu-add-to-menubar "PDF outline"))

(defun jao-doc-view--imenu-create-index ()
  (let (index)
    (dolist (item (or jao--pdf-outline
                      (setq jao--pdf-outline
                            (jao-doc-view-pdf-outline jao-doc-view--imenu-file))))
      (let-alist item
        (let* ((lvl (make-string (max 0 (1- .level)) ?.))
               (title (format "%s%s (%s)" lvl .title .page)))
          (push `(,title 0 jao-doc-view--go ,item) index))))
    (nreverse index)))

(defun jao-doc-view--go (&rest args)
  (when-let (item (car (last args)))
    (let-alist item (funcall jao-doc-view--goer .page))))

(add-hook 'doc-view-mode-hook #'jao-doc-view--enable-imenu)


;;; Page trailing
(defvar-local jao-doc-view--trail-back ())
(defvar-local jao-doc-view--trail-fwd ())

(defun jao-doc-view--trail-push (dest-page)
  (when-let (page (jao-doc-view-current-page))
    (unless (eq (car jao-doc-view--trail-back) page)
      (push page jao-doc-view--trail-back))))

(defun jao-doc-view-back ()
  (interactive nil doc-view-mode)
  (if-let (p (pop jao-doc-view--trail-back))
      (progn (push (jao-doc-view-current-page) jao-doc-view--trail-fwd)
             (jao-doc-view-goto-page p))
    (message "No more back marks.")))

(defun jao-doc-view-forward ()
  (interactive nil doc-view-mode)
  (if-let (p (pop jao-doc-view--trail-fwd))
      (progn (push (jao-doc-view-current-page) jao-doc-view--trail-back)
             (jao-doc-view-goto-page p))
    (message "No more forward marks.")))

(advice-add 'doc-view-goto-page :before #'jao-doc-view--trail-push)


;;; Find URLs
(defun jao-doc-view--page-urls (all)
  (if doc-view--current-converter-processes
      (message "DocView: please wait till conversion finished.")
    (let ((txt (expand-file-name "doc.txt" (doc-view--current-cache-dir)))
          (page (doc-view-current-page))
          (pd-rx (rx (+ (literal page-delimiter))))
          (urls))
      (if (file-readable-p txt)
          (with-current-buffer (find-file-noselect txt)
            (goto-char (point-min))
            (unless all (re-search-forward pd-rx nil t (1- page)))
            (let ((end (save-excursion
                         (if (and (not all) (re-search-forward pd-rx nil t))
                             (point)
                           (point-max)))))
              (while (re-search-forward "https?://" end t)
                (push (thing-at-point-url-at-point) urls))
              urls))
        (doc-view-doc->txt txt (lambda () (jao-doc-view--page-urls all)))
        'wait))))

(defun jao-doc-view-visit-url (all)
  "Visit URL displayed in this page."
  (interactive "P" doc-view-mode)
  (let ((urls (jao-doc-view--page-urls all)))
    (cond ((eq 'wait urls) (message "Extracting text, please wait and retry."))
          ((zerop (length urls)) (message "No URLs in this page"))
          (t (when-let (url (completing-read "URL: " urls nil nil
                                             (when (null (cdr urls)) (car urls))))
               (browse-url url))))))


(provide 'jao-doc-view)