;;; jao-pdf.el --- utilities for pdf files           -*- lexical-binding: t; -*-

;; Copyright (C) 2022  jao

;; Author: jao <mail@jao.io>
;; Keywords: docs

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; Some niceties for PDFs:
;;
;;   - Using mutools, we can extract the outline of PDFs, and tell back the
;;     section title of a given page.
;;   - Interoperability with zathura.

(require 'jao-doc-session)

;;; PDF info

(declare-function 'pdf-info-outline "pdf-info")

(defvar-local jao-pdf--outline nil)

(defun jao-pdf-is-pdf-file (file)
  "Simply checks the FILE extension."
  (string-match-p ".*\\.pdf$" file))

(defun jao-pdf-title-to-file-name (title)
  "Convert a title, possibly with embedded spaces, to a PDF filename."
  (concat (mapconcat 'downcase (split-string title nil t) "-") ".pdf"))

(defun jao-pdf-title (&optional fname)
  (if (or fname (not (derived-mode-p 'doc-view-mode 'pdf-view-mode)))
      (let ((base (file-name-base (or fname (buffer-file-name)))))
        (capitalize (replace-regexp-in-string "-" " " base)))
    (or (jao-pdf-section-title)
        (when buffer-file-name (jao-pdf-title buffer-file-name)))))

(defvar-local jao-pdf--outline nil)

(defun jao-pdf-section-title (&optional page file-name)
  (when (not jao-pdf--outline)
    (setq-local jao-pdf--outline (doc-view--pdf-outline file-name)))
  (let ((page (or page
                  (and (derived-mode-p 'doc-view-mode) (doc-view-current-page))
                  (and (derived-mode-p 'pdf-view) (pdf-view-current-page))))
        (outline jao-pdf--outline)
        (cur-page 0)
        (cur-title (jao-pdf-title (or file-name buffer-file-name "title"))))
    (while (and (car outline) page (< cur-page page))
      (setq cur-page (cdr (assoc 'page (car outline))))
      (when (<= cur-page page)
        (setq cur-title (cdr (assoc 'title (car outline)))))
      (setq outline (cdr outline)))
    (replace-regexp-in-string "[[:blank:]]+" " " cur-title)))

;;; zathura interop
(defun jao-pdf-zathura-open-cmd (file page &optional suffix)
  (let ((page (if page (format "-P %s" page) "")))
    (format "zathura %s %s %s" file page (or suffix ""))))

(defun jao-pdf-zathura-title-rx (file)
  (concat (file-name-nondirectory file) " \\[.+\\]"))

;; e.g.  "~/org/doc/write-yourself-a-scheme-in-48-hours.pdf [96 (96/138)]"
(defun jao-pdf-zathura-file-info (title)
  (when (string-match "\\(.+\\) \\[\\(.+\\) (\\([0-9]+\\)/\\([0-9]+\\))\\]"
                      title)
    (list (expand-file-name (match-string 1 title))
          (string-to-number (match-string 3 title))
          (string-to-number (match-string 4 title))
          (match-string 2 title))))

(defun jao-pdf--zathura-link (info)
  (when-let* ((file (car info))
              (page (cadr info))
              (no (or (car (last info)) page))
              (fn (file-name-nondirectory file))
              (lnk (format "doc:%s::%s" fn page))
              (desc (format "%s (p. %s)" (jao-pdf-section-title page file) no)))
    (org-make-link-string lnk desc)))

(defun jao-pdf-zathura-org-link (title)
  (jao-pdf--zathura-link (jao-pdf-zathura-file-info title)))

(provide 'jao-pdf)
;;; jao-pdf.el ends here