;;; jao-ednc.el --- Minibuffer notifications using EDNC  -*- lexical-binding: t; -*-

;; Copyright (C) 2020  jao

;; Author: jao <mail@jao.io>
;; Keywords: tools, abbrev

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;;  Use the ednc package to provide a notification daemon that uses
;;  the minibuffer to display them.

;;; Code:

(require 'ednc)
(require 'jao-minibuffer)

(defvar jao-ednc--count-format "{%d}")
(defvar jao-ednc--last-notification nil)

(defun jao-ednc--format-last ()
  (when jao-ednc--last-notification
    (let ((s (ednc-format-notification jao-ednc--last-notification t)))
      (replace-regexp-in-string "\n" " " s))))

(defun jao-ednc--count ()
  (let ((no (length (ednc-notifications))))
    (if (> no 0) (format jao-ednc--count-format no) "")))

(defun jao-ednc--on-notify (old new)
  (when old
    (setq jao-ednc--last-notification nil)
    (jao-minibuffer-pop-notification))
  (when new
    (setq jao-ednc--last-notification new)
    (jao-minibuffer-push-notification '(:eval (jao-ednc--format-last)))))

;;;###autoload
(defun jao-ednc-setup ()
  (with-eval-after-load "jao-notify"
    (defun jao-ednc--notify (msg &optional title _)
      (message "%s%s%s" (or title "") (if title " " "") msg))
    (advice-add 'jao-notify :override #'jao-ednc--notify))
  (jao-minibuffer-add-variable '(jao-ednc--count) t)
  (add-hook 'ednc-notification-presentation-functions #'jao-ednc--on-notify)
  (ednc-mode))

;;;###autoload
(defun jao-ednc-show ()
  (interactive)
  (pop-to-buffer-same-window "*ednc-log*"))

;;;###autoload
(defun jao-ednc-invoke-last-action ()
  (interactive)
  (if jao-ednc--last-notification
      (ednc-invoke-action jao-ednc--last-notification)
    (message "No active notifications"))
  (jao-minibuffer-pop-notification))

(provide 'jao-ednc)
;;; jao-ednc.el ends here