;;; jao-minibuffer.el --- using the minibuffer to report status  -*- lexical-binding: t; -*-

;; Copyright (C) 2020  jao

;; Author: jao <mail@jao.io>
;; Keywords: extensions

;; This program is free software; you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.

;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
;; GNU General Public License for more details.

;; You should have received a copy of the GNU General Public License
;; along with this program.  If not, see <https://www.gnu.org/licenses/>.

;;; Commentary:

;; Simple asynchronous display of information in the minibuffer.

;;; Code:

(defvar jao-minibuffer-info ())
(defvar jao-minibuffer-notification nil)
(defvar jao-minibuffer-align-right-p t)
(defvar jao-minibuffer-right-margin 2)
(defvar jao-minibuffer-maximized-frames-p t)

(defconst jao-minibuffer--name " *Minibuf-0*")

(defun jao-minibuffer--trim (s w)
  (if (<= (length s) w)
      (format (format "%%%ds" w) s)
    (substring s 0 w)))

(defun jao-minibuffer--aligned (&optional w)
  (let ((msg (string-trim (format-mode-line (or jao-minibuffer-notification
                                                jao-minibuffer-info)))))
    (when (not (string-empty-p msg))
      (if jao-minibuffer-align-right-p
          (let* ((mw (if jao-minibuffer-maximized-frames-p
                         (frame-width)
                       (window-width (minibuffer-window))))
                 (w (mod (or w 0) mw))
                 (w (- mw w jao-minibuffer-right-margin)))
            (if (> w 0) (jao-minibuffer--trim msg w) ""))
        (concat " · " msg)))))

(defun jao-minibuffer--message (old-func &rest args)
  (let* ((msg (let ((inhibit-message t)) (apply old-func args)))
         (msg (if inhibit-message "" msg))
         (new-msg (concat msg (jao-minibuffer--aligned (length msg))))
         (message-log-max nil)
         (inhibit-message nil))
    (funcall old-func "%s" new-msg)
    msg))

(advice-add #'message :around #'jao-minibuffer--message)

;;;###autoload
(defun jao-minibuffer-refresh ()
  (interactive "")
  (with-current-buffer jao-minibuffer--name
    (erase-buffer)
    (insert (or (jao-minibuffer--aligned) ""))))

;;;###autoload
(defun jao-minibuffer-add-variable (variable-name &optional append)
  (add-to-list 'jao-minibuffer-info `(:eval ,variable-name) append))

;;;###autoload
(defun jao-minibuffer-push-notification (msg)
  (setq jao-minibuffer-notification msg)
  (jao-minibuffer-refresh))

;;;###autoload
(defun jao-minibuffer-pop-notification ()
  (interactive)
  (setq jao-minibuffer-notification nil)
  (jao-minibuffer-refresh))

(provide 'jao-minibuffer)
;;; jao-minibuffer.el ends here