path: root/org.org

#+title: Org (and related) mode configuration

* General configuration
  #+BEGIN_SRC emacs-lisp
    (use-package org
      :ensure t
      :init
      (setq org-catch-invisible-edits 'smart
            org-complete-tags-always-offer-all-agenda-tags t
            org-cycle-separator-lines 0 ;; no blank lines when all colapsed
            org-deadline-warning-days 14
            org-default-notes-file (expand-file-name "inbox.org" org-directory)
            org-directory jao-org-dir
            org-display-remote-inline-images 'download ;; 'skip 'cache
            org-ellipsis " .." ;; ↴
            org-email-link-description-format "Email %c: %s"
            org-enforce-todo-dependencies t
            org-fast-tag-selection-single-key 'expert
            org-hide-emphasis-markers t
            org-hide-leading-stars t
            ;; org-list-demote-modify-bullet '(("+" . "-") ("-" . "+") ("*" . "+"))
            org-link-frame-setup
            '((gnus . (lambda (&optional x) (jao-open-gnus-frame)))
              (file . find-file-other-window))
            org-log-done nil
            org-modules '(bbdb bibtex info eww eshell git-link)
            org-odd-levels-only t
            org-outline-path-complete-in-steps nil
            org-refile-allow-creating-parent-nodes 'confirm
            org-refile-targets '((nil :maxlevel . 5)
                                 (org-agenda-files :maxlevel . 5))
            org-refile-use-outline-path 'file
            org-return-follows-link t
            org-reverse-note-order t
            org-special-ctrl-a/e t
            org-src-fontify-natively t
            org-startup-folded t
            org-tag-alist nil
            org-tags-column -75
            org-todo-keywords
            '((sequence "TODO(t)" "STARTED(s!)" "|" "DONE(d!)")
              (sequence "REPLY(r)" "WAITING(w!)" "|" "DONE(d!)")
              (sequence "TOREAD(T)" "READING(R!)" "|" "READ(a!)")
              (sequence "|" "CANCELLED(x!)" "SOMEDAY(o!)" "DONE(d!)"))
            org-use-fast-todo-selection t
            org-use-speed-commands nil ;; t and then ? to see help
            org-gnus-prefer-web-links nil))
    (require 'org)
  #+END_SRC
* Agenda
  #+begin_src emacs-lisp
    (setq org-agenda-custom-commands
          '(("w" todo "WAITING" nil)
            ("W" agenda "" ((org-agenda-ndays 21))))
          org-agenda-files (list jao-org-dir)
          org-agenda-include-diary t
          org-agenda-include-inactive-timestamps t
          org-agenda-inhibit-startup nil
          org-agenda-restore-windows-after-quit t
          org-agenda-show-all-dates t
          org-agenda-skip-deadline-if-done t
          org-agenda-skip-scheduled-if-done nil
          org-agenda-span 7
          org-agenda-start-on-weekday nil
          org-agenda-window-setup 'current-window)
  #+end_src
* Capture templates
  #+BEGIN_SRC emacs-lisp
    (setq  org-capture-templates
           '(("t" "TODO" entry
              (file+headline "inbox.org" "Todo")
              "* TODO %?\n  %i%a" :prepend t)
             ("r" "REPLY" entry
              (file+headline "inbox.org" "Todo")
              "* REPLY %:subject%?\n  %t\n %i%a" :prepend t)
             ("a" "Appointment" entry
              (file+olp "inbox.org" "Appointments")
              "* %^T %?\n  %a" :time-prompt t)
             ("i" "Inbox note" entry (file+headline "inbox.org" "Notes")
              "* %a\n  %i%?(added on: %u)" :prepend t)))
    ;; (org-capture-upgrade-templates org-capture-templates)
  #+END_SRC
* MIME and file apps
  #+BEGIN_SRC emacs-lisp
    (setq org-file-apps
          '((system . mailcap)
            (".*\\.djvu" . system)
            (t . emacs)))
  #+END_SRC
* LaTeX
  #+begin_src emacs-lisp
    (use-package org-fragtog
      :after org
      :ensure t
      :hook ((org-mode . org-fragtog-mode)))

    (require 'org-fragtog)

    (setq org-format-latex-options
          `(:foreground default
                        :background
                        ,(if (jao-colors-scheme-dark-p) "black" "white")
                        :scale 1.25
                        :html-foreground "black"
                        :html-background "Transparent"
                        :html-scale 1.0
                        :matchers ("begin" "$1" "$" "$$" "\\(" "\\["))
          org-preview-latex-image-directory
          (expand-file-name "~/.emacs.d/cache/ltximg/")
          org-latex-hyperref-template nil
          org-highlight-latex-and-related '(latex script entities))

    (require 'ox-latex)
    (add-to-list 'org-latex-classes
                 '("bmlarticle"
                   "\\documentclass{bmlarticle}\n[NO-DEFAULT-PACKAGES]\n[EXTRA]"
                   ("\\section{%s}" . "\\section*{%s}")
                   ("\\subsection{%s}" . "\\subsection*{%s}")
                   ("\\subsubsection{%s}" . "\\subsubsection*{%s}")
                   ("\\paragraph{%s}" . "\\paragraph*{%s}")
                   ("\\subparagraph{%s}" . "\\subparagraph*{%s}")))

    (use-package cdlatex
      :ensure t
      :hook ((org-mode . org-cdlatex-mode))
      :diminish ((cdlatex-mode . " £")
                 (org-cdlatex-mode . " £")))

  #+end_src

* Export (minted)

  #+begin_src emacs-lisp
    (setq org-latex-listings 'minted
          org-latex-packages-alist '(("" "minted"))
          org-latex-pdf-process
          '("pdflatex -shell-escape -interaction nonstopmode -output-directory %o %f"
            "pdflatex -shell-escape -interaction nonstopmode -output-directory %o %f"))
  #+end_src

* Babel
  - [[http://cachestocaches.com/2018/6/org-literate-programming][Literate Programming with Org-mode]]
  - [[http://howardism.org/Technical/Emacs/literate-devops.html][Literate DevOps]]

  #+begin_src emacs-lisp
    (setq org-src-window-setup 'other-window) ;; current-window
    (require 'org-tempo nil t) ;; <s TAB for 9.2 and later

    ;; (use-package ob-elixir
    ;;   :ensure t
    ;;   :after org)

    (use-package ob-prolog
      :ensure t
      :after org)

    (org-babel-do-load-languages
     'org-babel-load-languages
     '((calc . t)
       (clojure . t)
       ;; (elixir . t)
       (emacs-lisp .t)
       (gnuplot .t)
       (haskell . t)
       (makefile . t)
       (ocaml . t)
       (org . t)
       (python . t)
       (scheme .t)
       (shell . t)
       (prolog . t)))
  #+end_src

* Org cliplink (link from clipboard)
  [[https://github.com/rexim/org-cliplink][GitHub - rexim/org-cliplink: Insert org-mode links from clipboard]]

  #+BEGIN_SRC emacs-lisp
    (use-package org-cliplink
      :ensure t
      :bind (:map org-mode-map ("C-c C-f" . org-cliplink))
      :config
      (add-to-list 'org-capture-templates
                   '("k" "Cliplink capture task" entry
                     (file+headline "inbox.org" "Todo")
                     "* TODO %(org-cliplink-capture) %?" :prepend t)
                   t))
  #+END_SRC

* Notes
  #+begin_src emacs-lisp
    (use-package jao-org-notes
      :commands (jao-org-notes-setup)
      :config
      (major-mode-hydra-define+ org-mode ()
        ("Notes"
         (("i" jao-org-notes-insert-link "insert link")
          ("t" jao-org-notes-insert-tags "insert tags")
          ("o" jao-org-notes-open "find and open note")
          ("c" jao-org-notes-open-or-create "open or create note")
          ("v" jao-org-notes-backlinks "show backlinks"))))
      :bind (("C-c n" . jao-org-notes-open-or-create)
             ("C-c N" . jao-org-notes-open)))
    (jao-org-notes-setup "n")
  #+end_src
* Links
  #+begin_src emacs-lisp
    (require 'ol-eshell nil t)
    (require 'ol-bbdb nil t)
    (require 'ol-info nil t)
    (setq org-link-abbrev-alist '(("jao.io" "https://jao.io/")))

    (defun jao-org-link-at-point (&optional copy)
      (when (thing-at-point-looking-at "\\[\\[\\([^]]+\\)\\]\\[[^]]+\\]\\]")
        (when copy (kill-ring-save (match-beginning 1) (match-end 1)))
        (match-string-no-properties 1)))

    (defun jao-org-copy-link-at-point ()
      (interactive)
      (message "%s" (or (jao-org-link-at-point t) "No link at point")))

    (defun jao-org-insert-link (url title)
      (insert (format "[[%s][%s]]" url title)))

    (defun jao-insert-eww-link ()
      "Look for last eww buffer and insert an org link to it."
      (interactive)
      (when-let (b (car (last (jao-eww-session--list-buffers))))
        (let ((lnk (with-current-buffer b
                     (format "[[%s][%s]]" (eww-current-url) (jao-eww--title)))))
          (insert lnk))))

    (use-package jao-org-links
      :commands jao-org-links-setup
      :bind (("C-c T" . jao-org-insert-doc)))

    (jao-org-links-setup jao-sink-dir)

    (with-eval-after-load "pdf-view"
      (define-key pdf-view-mode-map (kbd "C-c o") #'jao-org-pdf-goto-org)
      (define-key pdf-view-mode-map (kbd "C-c O") #'jao-org-pdf-goto-org*))

    (with-eval-after-load "doc-view"
      (define-key doc-view-mode-map (kbd "C-c o") #'jao-org-pdf-goto-org)
      (define-key doc-view-mode-map (kbd "C-c O") #'jao-org-pdf-goto-org*))

    #+end_src
* Eldoc
  #+begin_src emacs-lisp
    (defun jao-org-eldoc--hook ()
      (set (make-local-variable 'eldoc-documentation-function)
           'jao-org-link-at-point)
      (eldoc-mode))
    (add-hook 'org-mode-hook 'jao-org-eldoc--hook)
  #+end_src
* Savedoc
  #+begin_src emacs-lisp
    (defun jao-org--show-if-hidden ()
      (when (outline-invisible-p)
        (save-excursion
          (outline-previous-visible-heading 1)
          (org-show-subtree))))
    (add-hook 'org-mode-hook 'jao-org--show-if-hidden t)
  #+end_src
* Keybindings
    #+begin_src emacs-lisp
      (define-key mode-specific-map [?a] 'org-agenda)
      (define-key org-mode-map "\C-cv" 'jao-org-copy-link-at-point)
      (define-key org-mode-map [(control ?c) tab] 'org-force-cycle-archived)
      (define-key org-mode-map [(f7)] 'org-archive-to-archive-sibling)
      (define-key org-mode-map "\C-cE" 'jao-insert-eww-link)
      (define-key org-mode-map "\C-c'" 'org-edit-src-code)
      (define-key org-mode-map "\C-cO" 'outline-hide-other)
      (global-set-key "\C-cr" 'org-capture)
      (global-set-key "\C-c\C-l" 'org-store-link)
      (global-set-key "\C-cL" 'org-insert-link-global)
      (global-set-key "\C-cO" 'org-open-at-point-global)
      (global-set-key "\C-ca" 'org-agenda)
    #+end_src